Al crear una instancia de TransactionScope mediante la instrucción new, el administrador de transacciones determina en qué transacción va a participar. Una vez determinada, el ámbito siempre participa en esa transacción. La decisión se basa en dos factores: si está presente una transacción de ambiente y el valor del parámetro TransactionScopeOption del constructor. La transacción de ambiente es aquélla en la que se ejecuta el código. Puede obtener una referencia a la transacción de ambiente llamando a la propiedad Current estática de la clase Transaction. Para obtener más información sobre la utilización de este parámetro, consulte la sección sobre administración del flujo de transacciones del tema Implementar una transacción implícita con el ámbito de transacción.

Si no se produce ninguna excepción dentro del ámbito de la transacción (es decir, entre la inicialización del objeto TransactionScope y la llamada de su método Dispose), entonces se permite que la transacción en la que participa el ámbito continúe. Si aparece una excepción dentro del ámbito de la transacción, se deshará la transacción en la que participa.

Cuando la aplicación termina todo el trabajo que tiene que llevar a cabo en una transacción, debe llamar al método Complete sólo una vez para notificar al administrador de transacciones que la transacción se puede confirmar. Si no se puede llamar a este método se anula la transacción.

Una llamada al método Dispose marca el fin del ámbito de la transacción. Las excepciones que aparecen después de llamar a este método quizá no afecten a la transacción.

Si modifica el valor de Current dentro de un ámbito, se produce una excepción cuando se llama al método Dispose. Sin embargo, al final del ámbito, se restaura el valor anterior. Además, si se llama a Dispose en Current dentro del ámbito de transacción que creó la transacción, la transacción se anula al final del ámbito

 Ejemplo

En el ejemplo siguiente se muestra cómo utilizar la clase TransactionScope para definir un bloque de código para participar en una transacción.

Visual Basic

Copiar código

'  This function takes arguments for 2 connection strings and commands to create a transaction 
'  involving two SQL Servers. It returns a value > 0 if the transaction is committed, 0 if the 
'  transaction is rolled back. To test this code, you can connect to two different databases 
'  on the same server by altering the connection string, or to another 3rd party RDBMS  
'  by altering the code in the connection2 code block.
Public Function CreateTransactionScope( _
  ByVal connectString1 As String, ByVal connectString2 As String, _
  ByVal commandText1 As String, ByVal commandText2 As String) As Integer

    ' Initialize the return value to zero and create a StringWriter to display results.
    Dim returnValue As Integer = 0
    Dim writer As System.IO.StringWriter = New System.IO.StringWriter

    ' Create the TransactionScope to execute the commands, guaranteeing
    '  that both commands can commit or roll back as a single unit of work.
    Using scope As New TransactionScope()
        Using connection1 As New SqlConnection(connectString1)
            Try
                ' Opening the connection automatically enlists it in the 
                ' TransactionScope as a lightweight transaction.
                connection1.Open()

                ' Create the SqlCommand object and execute the first command.
                Dim command1 As SqlCommand = New SqlCommand(commandText1, connection1)
                returnValue = command1.ExecuteNonQuery()
                writer.WriteLine("Rows to be affected by command1: {0}", returnValue)

                ' If you get here, this means that command1 succeeded. By nesting
                ' the using block for connection2 inside that of connection1, you
                ' conserve server and network resources as connection2 is opened
                ' only when there is a chance that the transaction can commit.   
                 Using connection2 As New SqlConnection(connectString2)
                    Try
                        ' The transaction is escalated to a full distributed
                        ' transaction when connection2 is opened.
                        connection2.Open()

                        ' Execute the second command in the second database.
                        returnValue = 0
                        Dim command2 As SqlCommand = New SqlCommand(commandText2, connection2)
                        returnValue = command2.ExecuteNonQuery()
                        writer.WriteLine("Rows to be affected by command2: {0}", returnValue)

                    Catch ex As Exception
                        ' Display information that command2 failed.
                        writer.WriteLine("returnValue for command2: {0}", returnValue)
                        writer.WriteLine("Exception Message2: {0}", ex.Message)
                    End Try
                End Using

            Catch ex As Exception
                ' Display information that command1 failed.
                writer.WriteLine("returnValue for command1: {0}", returnValue)
                writer.WriteLine("Exception Message1: {0}", ex.Message)
            End Try
        End Using

        ' The Complete method commits the transaction. If an exception has been thrown,
        ' Complete is called and the transaction is rolled back.
        scope.Complete()
    End Using

    ' The returnValue is greater than 0 if the transaction committed.
    If returnValue > 0 Then
        writer.WriteLine("Transaction was committed.")
    Else
       ' You could write additional business logic here, for example, you can notify the caller 
       ' by throwing a TransactionAbortedException, or logging the failure.
       writer.WriteLine("Transaction rolled back.")
     End If

    ' Display messages.
    Console.WriteLine(writer.ToString())

    Return returnValue
End Function

Mas información en la web de Micorsoft: http://msdn.microsoft.com/es-es/library/system.transactions.transactionscope(VS.80).aspx